ASP开发基于XML的留言板
XML（Extensible Markup Language）是一种基于文本格式的标记语言，它注重对数据结构和数据意义的描述，实现了数据内容和显示样式的分离，而且是与平台无关的。由于XML注重数据内容的描述，因而，对于数据的检索非常有意义，我们不会再象HTML那样，检索出与我们要求无关的信息。另一方面，XML文件是数据的载体，利用XML作为数据库，不需要访问任何数据库系统，我们可以使用任意WEB技术来显示我们的数据，比如HTML，Flash 5 等。由于世界各大计算机公司的积极参与，XML正日益成为基于互联网的数据格式新一代的标准。下面利用XML作为数据的载体，开发一个基于XML的留言板。
首先，我们建立XML文件guestbook.xml，该文件记录了留言者的姓名、电子邮件、网址、留言内容。当然，我们也可以根据需要添加任意多的信息。
文件内容如下：
<?xml version="1.0" encoding="gb2312"?> <留言本> <留言记录> <留言者姓名>孟宪会</留言者姓名> <电子邮件>amxh@testDomain.com</电子邮件> <网址>http://go.163.com/~colorweb</网址> <留言内容>测试成功！！</留言内容> </留言记录> </留言本>
由于目前许多服务器都支持ASP，我们采用常见的ASP来作为实现的工具，guestbook.asp文件如下：
<%@Language="VBScript"%>
<%
'设置Web页面的信息
Response.Buffer = true
Response.Expires = -1
'显示留言函数init()
Function init()
entryForm()
'定义局部变量
Dim objXML
Dim arrNames
Dim arrEmails
Dim arrURLS
Dim arrMessages
'创建XMLDOM文档对象，用来存放留言
Set objXML = server.createObject("Msxml2.DOMDocument")
objXML.async = false
objXML.load(server.MapPath("guestbook.xml"))
'取得留言本各元素的集合
Set arrNames = objXML.getElementsByTagName("留言者姓名")
Set arrEmails = objXML.getElementsByTagName("电子邮件")
Set arrURLS = objXML.getElementsByTagName("网址")
Set arrMessages = objXML.getElementsByTagName("留言内容")
Response.Write "<table border='0' width='100%'>"
Response.Write "<tr><td bgcolor='#00CCFF' align='center' height='26'>"
Response.Write "<b>各位的留言如下：</b>"
Response.Write "</td></tr>"
'输出留言本各元素的内容，最新的留言先显示
For x=arrNames.length-1 To 0 Step -1
Response.Write "<tr><td><a href=mailto:" & arrEmails.item(x).text & ">" & arrNames.item(x).text & "</a></td></tr>"
Response.Write "<tr><td>网址：<a href=" & arrURLS.item(x).text & " target='_blank'>" & arrURLS.item(x).text & "</a><td></tr>"
Response.Write "<tr><td>留言内容：</td></tr>"
Response.Write "<tr><td bgcolor='#0099ff'>" & arrMessages.item(x).text &"</td></tr>"
Response.Write "<tr><td> </td></tr>"
Next
Response.Write "</table>"
Set objXML = nothing
End Function
'向XML文件添加留言记录的函数addEntry()
Function addEntry()
'定义局部变量
Dim strName
Dim strEmail
Dim strURL
Dim strMessage
'取得留言表单的输入内容
strName = Request.Form("姓名")
strEmail = Request.Form("电子邮件")
strURL = Request.Form("网址")
strMessage = Request.Form("留言")
Dim objXML
Dim objEntry
Dim objName
Dim objEmail
Dim objURL
Dim objMessage
'向XML文件添加留言内容
Set objXML = server.createObject("Msxml2.DOMDocument")
objXML.async = false
objXML.load(server.MapPath("guestbook.xml"))
Set objEntry = objXML.createNode("element", "留言记录", "")
objXML.documentElement.appendChild(objEntry)
Set objName = objXML.createNode("element", "留言者姓名", "")
objEntry.appendChild(objName)
objName.text = strName
Set objEmail = objXML.createNode("element", "电子邮件", "")
objEntry.appendChild(objEmail)
objEmail.text = strEmail
Set objURL = objXML.createNode("element", "网址", "")
objEntry.appendChild(objURL)
objURL.text = strURL
Set objMessage = objXML.createNode("element", "留言内容", "")
objEntry.appendChild(objMessage)
objMessage.text = strMessage
objXML.save(server.MapPath("guestbook.xml"))
Response.Redirect("guestbook.asp")
End function
'填写和发送留言表单的函数entryForm()
Function entryForm()
Response.Write "<p align='center'><b>XML 留言本 例子</b></p>"
Response.Write "<hr color='#000099' width='100%' noshade>"
Response.Write "<form action=guestbook.asp?action=addEntry method=post>"
Response.Write "<table border=1>"
Response.Write "<tr><td>您的姓名：</td><td><input type=text name=姓名 /></td></tr>"
Response.Write "<tr><td>电子邮件：</td><td><input type=text name=电子邮件 /></td></tr>"
Response.Write "<tr><td>您的网址：</td><td><input type=text name=网址 /></td></tr>"
Response.Write "<tr><td>您的留言：</td><td><textarea name=留言 cols=40 rows=5></textarea></td></tr>"
Response.Write "<tr><td> </td><td><input type=submit value=发布留言 /></td></tr>"
Response.Write "</table>"
Response.Write "</form>"
End Function
%>
<html>
<head>
<title>XML 留言例子</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
</head>
<body>
<%
'判断是否发送了留言，并更新留言信息
Dim a
a = Request.Querystring("action")
If a<>"" Then
addEntry
else
init
End If
%>
</body>
</html>
以上是利用XML开发留言板简单的例子，可以根据需要进行添加更多的功能。
相关推荐
-
LINQ to XML的编程基础
一.LINQ to XML 编程基础 1.LINQ to XML类 System.Xml.Linq命名空间含有19个类,下表列出了它们的名称及其描述: 类 描述 XAttribute 表示一个 XML 属性 XCData 表示一个 CDATA 文本节点 XComment 表示一个 XML 注释 XContainer 适用于可能具有子节点的所有节点的抽象基类 XDeclaration 表示一个 XML 声明 XDocument 表示一个 XML 文档 XDocumentType 表示一个 XML
-
服务器XMLHTTP(Server XMLHTTP in ASP)基础知识
相对于 Ajax,服务端 XMLHTTP 就是在服务端使用 XMLHttpRequest 对象了.虽然说,在服务端使用异步请求是比较不方便的,但是做为可以服务端发送 HTTP 请求的组件,学习一下也是没有坏处的. 这里,我讲的是在 ASP 环境中使用服务端 XMLHttpRequest,并以 JScript 做为演示代码的语言,因此,你需要了解 ASP 以及 JScript. 服务端 XMLHTTP,通常会用在获取远程主机的网页或者其他内容,新闻聚合系统一般就是使用服务端 XMLHTTP 对象来
-
C#实现的XML操作类实例
本文实例讲述了C#实现的XML操作类.分享给大家供大家参考.具体如下: 这里讲述了C#写的一个XML操作类,包括读取/插入/修改/删除. using System; using System.Data; using System.Configuration; using System.Web; using System.Web.Security; using System.Web.UI; using System.Web.UI.WebControls; using System.Web.UI.W
-
jQuery处理xml格式的返回数据(实例解析)
在这个示例程序中,我将使用$.ajax()方法,使用$.get()方法也可以,但我觉得$.ajax()更好一些,代码更容易懂,并且也不怎么复杂. 复制代码 代码如下: //定义用户名校验的方法function verify(){ //首先测试一下页面的按钮按下,可以调用这个方法 //使用javascript的alert方法,显示一个探出提示框 //alert("按钮被点击了!!!"); //1.获取文本框中的内容 //document.getElement
-
C# XML与Json之间相互转换实例详解
对于这转换其实很简单,其中最重要的就是先要引用类库.可以到官网进行下载引用http://json.codeplex.com. XML转换为Json字符串 复制代码 代码如下: string xml = @"<?xml version=""1.0"" standalone=""no""?> <root>
-
C#简单写入xml文件的方法
本文实例讲述了C#简单写入xml文件的方法.分享给大家供大家参考.具体实现方法如下: static void writeTree(XmlNode xmlElement, int level) { String levelDepth = ""; for(int i=0;i<level;i++) { levelDepth += " "; } Console.Write("\n{0}<{1}",levelDepth,xmlElement.N
-
asp控制xml数据库的经典代码
NO.1--建立一个XML数据库data.xml <?xml version="1.0"?> <records> <record> <name>caca</name> <qq>154222225</qq> <email>root@3ney.com</email> </record> <records> NO.2--建立对象CreateObject 建立da
-
C#写入对象或集合类型数据到xml文件的方法
本文实例讲述了C#写入对象或集合类型数据到xml文件的方法.分享给大家供大家参考.具体实现方法如下: public static string SerializeToXmlString(object objectToSerialize) { MemoryStream memoryStream = new MemoryStream(); System.Xml.Serialization.XmlSerializer xmlSerializer = new System.Xml.Serializati
-
DOM基础及php读取xml内容操作的方法
本文实例讲述了DOM基础及php读取xml内容操作的方法.分享给大家供大家参考.具体分析如下: DOM(Document Object Model):文档对象模型.核心思想是:把 xml文件看作是一个对象模型,然后通过对象的方式来操作 xml 文件. php对xml文档进行增删改查(curd)操作,具体分析如下: xml文档:class.xml 复制代码 代码如下: <?xml version="1.0" encoding="utf-8"?> <c
-
ajax 入门基础之 XMLHttpRequest对象总结
XMLHttpRequest 提供客户端同http服务器通讯的协议 一:创建 IE : http_request = new ActiveXObject("Msxml2.XMLHTTP"); http_request = new ActiveXObject("Microsoft.XMLHTTP"); 非IE: http_request = new XMLHttpRequest(); 二:onreadystatechange 指定当readyState属性改变时的事件
-
android开发基础教程—三种方式实现xml文件解析
1.sax方式 复制代码 代码如下: /** * 使用sax解析 */ public class SaxParse{ /** * sax解析器 */ private SAXParser parser; public SaxParse(){ try { SAXParserFactory f = SAXParserFactory.newInstance(); parser = f.newSAXParser(); } catch (ParserConfigurationException e) { e
-
PHP中开发XML应用程序之基础篇 添加节点 删除节点 查询节点 查询节
一. XML简介 XML(可扩展的标注语言)是一种W3C标准,主要用于Web应用程序和服务器之间实现容易的交互.数据的存储与使用. 使用XML标准编码的数据具有能容易被人和计算机解释的意义和结构.XML数据是平台和应用程序独立的.不用多说,这本身就使XML成为适合于互联网的一个理想的数据交换格式(事实上,它正是因这一用途而被开发的).最近,宽带连接的增长及消费者对于越过任何媒体进行数据共享的应用软件的需求意味着,XML Web服务和应用软件正变得越来越丰富. XML的发明正是为了解决描述网上丰富
-
初识XML基础知识
XML定义: 用于标记电子文件使其具有结构性的标记语言,可以用来标记数据.定义数据类型,是一种允许用户对自己的标记语言进行定义的源语言. XML发展史? 简单提一下Markup Language历史: 1969:GML(Generalized Markup Language)--(IBMResearch) 1968: SGML(Standard Generalized Markup Language)--(ISO) 1989:HTML(Hypertext Markup Language)--T