把HTML表单提交的数据转化成XML文件
通常，在asp中进行的form表单提交的数据都被写进数据库管理系统中去，如果你想要你的数据是方便携带的数据，你可以把它写进一个XML文件中去。这种方法是跨平台的，因此你所收集的信息不需要进行转换。
为了实现上面的想法，你必须先利用Microsoft XMLDOM建立一个XML文件，Microsoft XMLDOM对象有一个扩展对象库，它可以创建组成XML文件所需要的元素、属性、属性值。
当XMLDOM对象实例化以后，必须对各个元素进行引用来建立XML的结构，下面的例子就是先建立根元素，并把她追加到XML文件中；然后创建各个子元素，并追加元素的属性值。最后保存为XML文件。
实例化 Microsoft XMLDOM Object:
代码如下:
<%
Dim objDom
Dim objRoot
Dim objChild1
Dim objChild2
Dim objPI
Set objDom = Server.CreateObject("Microsoft.XMLDOM")
Set objRoot = objDom.createElement("rootElement")
objDom.appendChild objRoot
Set objChild1 = objDom.createElement("childElement1")
objRoot.appendChild objChild1
Set objChild2 = objDom.createElement("childElement2")
objRoot.appendChild objChild2
Set objPI = objDom.createProcessingInstruction("xml","version='1.0'")
objDom.insertBefore objPI, objDom.childNodes(0)
objDom.Save "c:MyXMLDoc.xml"
%>
一旦你保存了文件，用IE5+打开后，样式如下[当然，属性还没有被赋值]：
MyXMLDoc.xml: <?xml version="1.0"?>
<rootElement>
<childElement1 />
<childElement2 />
</rootElement>
下面我们来看看怎样利用这个对象来存储用户的输入信息。
首先建立输入表单的页面。
EnterContact.html:
代码如下:
<html>
<head>
<title>
通讯信息
</title>
</head>
<body>
<form action="processForm.asp" method="post">
<h3>请输入您的通讯信息：</h3>
姓 名: <input type="text" id="Name" name="姓名"><br>
性 别: <input type="text" id="sexName" name="性别"><br>
地 址: <input type="text" id="address" name="地址"><br>
工作单位: <input type="text" id="company" name="工作单位"><br>
电 话: <input type="text" id="phone" name="电话"><br>
电子邮件: <input type="text" id="email" name="电子邮件"><br>
<input type="submit" id="btnSub" name="btnSub" value="提交"><br>
</form>
</body>
</html>
然后编写ASP代码，遍历表单元素，并把输入的信息写进XML文件。
processForm.asp:
代码如下:
<%
'--------------------------------------------------------------------
'函数 "ConvertFormtoXML"接收传递的参数。
'strXMLFilePath - XML存放的物理地址。
'strFileName - 要保存的XML文件的名字。
'--------------------------------------------------------------------
Function ConvertFormtoXML(strXMLFilePath, strFileName)
'定义本地变量.
Dim objDom
Dim objRoot
Dim objField
Dim objFieldValue
Dim objattID
Dim objattTabOrder
Dim objPI
Dim x
'实例化Microsoft XMLDOM对象.
Set objDom = server.CreateObject("Microsoft.XMLDOM")
objDom.preserveWhiteSpace = True
'创建XML文档的根元素contact，并追加到XML文档中。
Set objRoot = objDom.createElement("通讯录")
objDom.appendChild objRoot
'遍历Request对象Form元素的集合。
For x = 1 To Request.Form.Count
If instr(1,Request.Form.Key(x),"btn") = 0 Then
'创建元素 "field".
Set objField = objDom.createElement("field")
'创建属性 "id".
Set objattID = objDom.createAttribute("id")
'设定id属性的值等于Form中各元素的值。
objattID.Text = Request.Form.Key(x)
'setAttributeNode 方法把id属性值追加到field元素。
objField.setAttributeNode objattID
'创建属性taborder。
Set objattTabOrder = objDom.createAttribute("taborder")
'设定taborder的属性值
objattTabOrder.Text = x
'把taborder的属性值追加到field元素中去。
objField.setAttributeNode objattTabOrder
'创建一个新的元素field_value.
Set objFieldValue = objDom.createElement("field_value")
'赋值
objFieldValue.Text = Request.Form(x)
'追加field元素为根元素的子元素。
objRoot.appendChild objField
'追加field_value做为子元素的内容
objField.appendChild objFieldValue
End If
Next
'创建xml声明
Set objPI = objDom.createProcessingInstruction("xml", "version='1.0' encoding='gb2312'")
'把xml生命追加到xml文档
objDom.insertBefore objPI, objDom.childNodes(0)
'保存xml文件
objDom.save strXMLFilePath & "" & strFileName
'释放所有对象所引用的值
Set objDom = Nothing
Set objRoot = Nothing
Set objField = Nothing
Set objFieldValue = Nothing
Set objattID = Nothing
Set objattTabOrder = Nothing
Set objPI = Nothing
End Function
'发生错误时继续执行
On Error Resume Next
'调用函数ConvertFormtoXML把文件存放到指定的文件目录和文件名。
ConvertFormtoXML "D:aspexam","Contact.xml"
'如果发生错误，提示用户，否则报告成功。
If err.number <> 0 then
Response.write("保存form值出现错误！！！")
Else
Response.write("提交成功！！")
End If
%>
用IE5+打开Contact.xml文件.
相关推荐
-
把HTML表单提交的数据转化成XML文件
通常,在asp中进行的form表单提交的数据都被写进数据库管理系统中去,如果你想要你的数据是方便携带的数据,你可以把它写进一个XML文件中去.这种方法是跨平台的,因此你所收集的信息不需要进行转换. 为了实现上面的想法,你必须先利用Microsoft XMLDOM建立一个XML文件,Microsoft XMLDOM对象有一个扩展对象库,它可以创建组成XML文件所需要的元素.属性.属性值. 当XMLDOM对象实例化以后,必须对各个元素进行引用来建立XML的结构,下面的例子就是先建立根元素,并
-
php 表单提交大量数据发生丢失的解决方法
最近在项目中,出现一个奇怪的现象,有一个大form里面有上千个input,提交的时候,老是发现post过来的数据不完整,一开始还怀疑是html 表单名称有冲突,排除掉了.然后,网上找了一堆,php.ini 的post_max_size和upload_max_filesize都设置了很大的值,没用,nginx的client_max_body_size 500m;加到了那么大的值,也没用.最后终于google到办法:原来PHP从5.3.9开始增加一个变量 max_input_vars 用来限制提交的
-
springmvc后台基于@ModelAttribute获取表单提交的数据
1.通过注解ModelAttribute直接映射表单中的参数到POJO.在from中的action写提交的路径,在input的name写参数的名称. POJO package com.demo.model; public class user { private String username; private String password; private int nsex; public String getUsername() { return username; } public vo
-
HttpClient实现表单提交上传文件
本文实例为大家分享了HttpClient实现表单提交上传文件的具体代码,供大家参考,具体内容如下 需求:如何利用HttpClient,发起post请求,模拟表单提交,在后端上传文件? 上传文件接口: /** * 文件上传测试接口 * @return */ @PostMapping("/upload") public Object uploadFileTest(@RequestParam("file") Multipart
-
Asp.Net模拟表单提交数据和上传文件的实现代码
如果你需要跨域上传内容到另外一个域名并且需要获取返回值,使用Asp.Net的作为代理是最好的办法,要是客户端直接提交到iframe中,由于跨域是无法用javascript获取到iframe中返回的内容的.此时需要在自己的网站做一个动态页作为代理,将表单提交到动态页,动态页负责将表单的内容使用WebClient或HttpWebRequest将表单数据再上传到远程服务器,由于在服务器端进行操作,就不存在跨域问题了. WebClient上传只包含键值对的文本信息示例代码: 复制代码 代码如下: str
-
基于JavaScript实现带数据验证和复选框的表单提交
实现: 1.用户至少选中某项,即表示选中该行,同时该行的数据验证通过,表单提交:否则,不提交. html <!DOCTYPE html> <html lang="en"> <head> <meta charset="UTF-8"> <title>带数据验证和复选框的表单提交</title> <script src="../commonJqery/jquery-3.0.0.js&q
-
BootStrap+Mybatis框架下实现表单提交数据重复验证
效果: jsp页面: <form class="form-horizontal lui-tj-bd" id="dbc_code_add_form" method="post"> <div class="row"> <div class="col-xs-12"> <!-- PAGE CONTENT BEGINS --> <div class="t
-
PHP实现表单提交数据的验证处理功能【防SQL注入和XSS攻击等】
本文实例讲述了PHP实现表单提交数据的验证处理功能.分享给大家供大家参考,具体如下: 防XSS攻击代码: /** * 安全过滤函数 * * @param $string * @return string */ function safe_replace($string) { $string = str_replace('%20','',$string); $string = str_replace('%27','',$string); $string = str_replace('%2527',
-
解决Layui 表单提交数据为空的问题
坑的外观 最近用了一段时间Layui作为项目后台管理模块的前端框架,感觉还是挺好用的. 今天踩了个坑,就是使用layui表单提交时,提交的数据为空. 例如,layer.msg(JSON.stringify(data.field));这句代码执行后,页面显示为空对象. <form class="layui-form" action=""> <div class="layui-form-item"> <label cla
-
layui form表单提交之后重新加载数据表格的方法
HTML form表单 <p style="text-align: center"><img src="//files.jb51.net/file_images/article/201909/20190911173925.jpg" alt="" /></p> <div class="layui-row"> <form class="layui-form layui