批处理 Set 命令详解让你理解set命令

2024-09-29 13:04:21

一、使用 set 命令进行赋值

SET [variable=[string]]

1、等号两边不要有空格

正确写法

C:\>set str=ScriptHome
C:\>echo %str%
ScriptHome

错误写法

C:\>set str = ScriptHome
C:\>echo %str%
%str%

2、变量值包含特殊字符需用双引号

正确写法

C:\>set "str=Bat&Home"
C:\>echo "%str%"
"Bat&Home"

错误写法

C:\>set str=Bat&Home
'Home' 不是内部或外部命令，也
不是可运行的程序或批处理文件。
C:\>echo "%str%"
"Bat"

变量值设置为空可以清空变量值，实现变量初始化。

3、避免使用系统环境变量同名的自定义变量

例如：

path , date , errorlevel 等

4、语法可行但不推荐使用

使用连等把多个变量赋值成数字 set /a x=y=100
逗号分隔把多个变量赋值成数字 set /a x=1,y=2

上面是dos界面下的写法，下面是批处理中的写法，主意是变量

示例1:

显示所有的变量的值

@echo off
set
pause

示例2:

@echo off
set var=我是值
echo %var%
pause

请看 set var=我是值 ,这就是BAT直接在批处理中设置变量的方法!
set 是命令 var是变量名 =号右边的"我是值"是变量的值
在批处理中我们要引用这个变量就把var变量名用两个%(百分号)扩起来,如%var%

二、SET /P variable=[promptString]

有时候我们需要提供一个交互界面,让用户自己输入变量的值,然后我们在来根据这个值来做相应操作,现在我就来说说这SET的这种语法,只需要加一个"/P"参数就可以了!

实例1:

@echo off
set /p var=请输入你的名字:
echo 您的名字是:%var%
pause

set /p 是命令语法 var是变量名 =号右边的"请输入变量的值: ",这个是提示语,不是变
量的值了!
运行后,我们在提示语后面直接输入robin,就会显示一行您” 您的名字是:robin”

@echo off
set /p var=请输入变量的值:
if %var% == 1 echo 您输入了 1 ~_~
pause

三、SET /A expression

/A 命令行开关指定等号右边的字符串为被评估的数字表达式。
该表达式解析很简单并以递减的优先权顺序支持下列操作:

() - 分组
! ~ - - 一元运算符
* / % - 算数运算符
+ - - 算数运算符
<< >> - 逻辑移位
& - 按位“与”
^ - 按位“异”
| - 按位“或”
= *= /= %= += -= &= ^= |= <<= >>= - 赋值
, - 表达式分隔符

set的/A参数就是让SET可以支持数学符号进行加减等一些数学运算!
现在开始举例子介绍这些数学符号的用法:
看例子这里的例子请直接在CMD下拷贝命令运行,不需要保存为BAT!

set /a var=1 + 1

set /a 语法, var变量名 1 + 1 数学式子
拷贝运行后会直接显示一个2,或者运行完后我们输入echo %var%,也是二,这就是一个简单的加法运算!

set /a var=2 - 1 结果是多少呢?如果你看不到结果就echo %var%.....
set /a var=2 * 2 乘法运算
set /a var=2 / 2 除法运算
set /a var=(1+1) + (1+1) 结果等于4 看得懂吧!

实例1：

@echo off
set /a a=1+1,b=2+1,c=3+1
echo %a% %b% %c%

实例2：

@echo off
set a=100
set b=1000
set /a c=a+b
echo the result is :%c%
pause

有时候我们需要直接在原变量进行加减操作就可以用这种语法

set /a var+=1 这样的语法对应原始语法就是set /a var = %var% + 1

都是一样的结果,在原变量的值上在进行数学运算,不过这样写简单一点
在来一个:

set /a var*=2

其他都这么用,只要帮助里有这个语法!
另外还有一些用逻辑或取余操作符,这些符号,按照上面的使用方法会报错的
比如我们在CMD里输入set /a var=1 & 1 "与运算",他并不会显示为1,而是报错,
为什么?对于这样的"逻辑或取余操作符",我们需要把他们用双引号引起来,看例子

set /a var= 1 "&" 1 这样结果就显示出来了,其他逻辑或取余操作符用法
set /a var= 1 "^" 1 异运算
set /a var= 1 "%" 1 取模运算
set /a var= 2 "<<" 2 位左移
set /a var= 4 ">>" 2 位右移

实例3：

@echo off
set a=100
set b=1000
set /a c=a+b
set /a c= c "<<" 2
echo the result is :%c%
pause

这些符号也可以用&= ^= |= <<= >>= 这样的简单用法如
set /a var"&=" 1 等于set /a var = %var% "&" 1 注意引号

实例4：

@echo off
set p=123
title 密码是%p%
set n=1
:in
if %n% gtr 3 goto wrong
set /p a=请输入您需要登陆的密码:
if "%a%" equ "%p%" goto right
set/a n+=1
goto in
:right
echo 猜对了，新年快乐！
goto end
:wrong
echo 已经输过3次了，还不正确，退出！
:end
pause

四、set的通常用法示例

1、set 显示环境变量：

如：在命令行下输入：
set 会显示当前所有的系统环境变量
set c 会显示所有的以c开头或C开头的变量（也即不区分大小写）；
set com 会显示所有的以com开头或COM开头的变量（不区分大小写）；

2、set 设置环境变量

用法示例：set 表达式

如：set str=ok
就是将变量str的值设置成字符串“OK”
注意：set str=ok>
这个在批处理运行过程中会出错，系统会提示：“命令语法不正确。”
原因是，因为变量str 中的值“ok>”的字符">"为一特殊字符，会被系统当成定向符处理，所以会运行出错，那如果确实要设置这样的变量str，值为 "ok>"怎么办呢？解决办法有二：将特殊字符转义，转义方法在该特殊字符前加一个“^”，如：set str=ok^> (这种方法比较少用，因为没有多少应用价值)
常见的解决办法，在set后面将整个表达式用引号括起来，如：set "str=>"

3、带参数 /a的set 数值计算

set的/A参数就是让SET可以支持数学符号进行加减等一些数学运算! 支持的数学运算包含（优先权递减）:

() - 分组
! ~ - - 一元运算符
* / % - 算数运算符
+ - - 算数运算符
<< >> - 逻辑移位
& - 按位“与”
^ - 按位“异”
| - 按位“或”
= *= /= %= += -= - 赋值
&= ^= |= <<= >>=
, - 表达式分隔符

用法示例：set /a num=2*10,这样变量num的值将变为：20

set /a var=2 - 1 结果是多少呢?如果你看不到结果就echo %var%.....
set /a var=2 * 2 乘法运算
set /a var=2 / 2 除法运算
set /a var=(1+1) + (1+1) 结果等于4 看得懂吧!
set /a a=1+1,b=2+1,c=3+1 运行后会显示一个4,但我们用
echo %a% %b% %c%后看结果,会发现其他数学运算也有效果!,这就是"斗"号的
作用!

有时候我们需要直接在原变量进行加减操作就可以用这种语法
set /a var+=1 这样的语法对应原始语法就是set /a var = %var% + 1
都是一样的结果。
对于"逻辑或取余操作符",我们需要把他们用双引号引起来,看例子

set /a var= 1 "&" 1 这样结果就显示出来了,其他逻辑或取余操作符用法
set /a var= 1 "+" 1 异运算
set /a var= 1 "%" 1 取模运算
set /a var= 2 "<<" 2 次方运算
set /a var= 4 ">>" 2 这个不太记得数学里的叫法....

这些符号也可以用&= ^= |= <<= >>= 这样的简单用法如
set /a var"&=" 1 等于set /a var = %var% "&" 1 注意引号

4、带参数 /p 的set 等待用户输入

windows 2000 和windows 是没有choice这个命令，choice的等待用户输入功能就要通过set /p来实现

演示如下：

@echo off
set /p str=请输入你想输入的字符：
echo 你输入的字符串为：%str%
pause>nul

set /p的特殊应用（set /p=<nul相当于输出字符并不带回车，利用这个性质，可以做出比较漂亮的动画），用法示例：

@echo off
for /l %%i in (1 1 70) do (
set /p=O<nul
for /l %%a in (1 1 50) do ver>nul
)
pause>nul

注：代码中用到了一句for /l %%a in (1 1 50) do ver>nul，它的目的是利用for循环运行某一命令来达到延时的目的。

5、利用set截取字符

字符串截取 set sub=%str:~x,y%

%Var:~start,len%

注意：从0开始。
例如：

@echo off
set a=www.jb51.net
set var=%a:~1,2%
echo %var%
pause

2、%Var:~-len%

截取倒数len位

3、%Var:~0,-len%

截取从第一位开始，倒数第len位结束的值。

例子

@echo off
set a=www.jb51.net
set var=%a:~0,-3%
echo %var%
pause

执行后,我们发现显示的是"www.jb51.net",少了"et"
从结果分析,很容易分析出,这是把变量a的值从0位开始,
到倒数第三位之间的值全部赋予给var

看不懂的同学可以查看下面这个图片

保存下面的代码为test.bat运行查看即可。

@echo off&color 1f&rem num=15 nums=30
mode con: cols=80 lines=35
set "var=1234567890"
set "num= "
set "nums= "
rem 第一屏 舍弃
cls&echo 第一屏 舍弃
echo\&echo %num% var=%var%&echo\
for /l %%i in (1 1 3) do call :dan %%i
echo\
for /l %%i in (0 1 1) do call :yi %%i
echo\
for /l %%i in (0 1 2) do call :_yi %%i
echo ~ 波浪号后面的数字：为正数表示舍弃变量的前位;
echo , 逗号后面的数字为正数表示取变量的舍弃以后的前几位;
echo , 逗号后面为负数表示舍弃变量的后几位
echo\&echo\&pause&color 1e
rem 第二屏 取
cls&echo 第二屏 取
echo\&echo %num% var=%var%&echo\
for /l %%i in (-1 -1 -3) do call :dan %%i
echo\
for /l %%i in (-4 -1 -6) do call :er %%i
echo\
call :_er -8
echo ~ 波浪号后面直接跟负数表示取变量的后几位
echo , 逗号后面的数字为正数表示取变量的舍弃以后的前几位;
echo , 逗号后面为负数表示舍弃变量的后几位
echo\&echo\&pause&color 1f
rem 第三屏 替换 删除
cls&echo 第三屏 替换 删除
set "var=abc:\123\ef:g\123\456"hij"789"klm\"
echo\&echo %num%var=%var%
echo\
call :san
echo = 号左边为要替换掉的字符, 右边为需替换来的字符
echo = 号左边要替换掉的字符前面加个*号,代表第一次出现的字符及其前面的所有字符
echo\
echo ========= 演示完毕 ========= 按任意键退出 ==========
pause>nul
exit
:dan
set shu=%1
if %shu% lss 0 (set aa=取&set ji=最后) else set aa=舍弃&set ji=前
if "%shu:~0,1%"=="-" set shu=%shu:~1%
set str1=%%var:~%1%%%num%
set str2=%aa%var的%ji%%shu%位%nums%
call set str3=%%var:~%1%%%num%
call echo %%str1:~0,15%% %%str2:~0,30%% %%str3:~0,15%%
goto :eof
:yi
set shu=%1
if %shu% lss 0 (set aa=取&set ji=最后) else set aa=舍弃&set ji=前
for /l %%i in (1 1 3) do (
set str1=%%var:~%1,%%i%%%num%
set str2=%aa%var的%ji%%shu%位之后取%%i位%nums%
call set str3=%%var:~%1,%%i%%%num%
call echo %%str1:~0,15%% %%str2:~0,26%% %%str3:~0,15%%
if %%i==3 echo\
)
goto :eof
:_yi
for /l %%i in (-1 -1 -3) do (
set str1=%%var:~%1,%%i%%%num%
set str2=舍弃var的前%1位和%%i位%nums%
call set str3=%%var:~%1,%%i%%%num%
call echo %%str1:~0,15%% %%str2:~0,28%% %%str3:~0,15%%
if %%i==-3 echo\
)
goto :eof
:er
set sss=%1
set sss=%sss:~1%
for /l %%i in (1 1 3) do (
set str1=%%var:~%1,%%i%%%num%
set str2=从var的倒数%sss%位开始取%%i位%nums%
call set str3=%%var:~%1,%%i%%%num%
call echo %%str1:~0,15%% %%str2:~0,24%% %%str3:~0,15%%
if %%i==3 echo\
)
goto :eof
:_er
set sss=%1
set sss=%sss:~1%
for /l %%i in (-1 -1 -3) do (
set str1=%%var:~%1,%%i%%%num%
set str2=从var的倒数%sss%位开始并舍弃最后%%i位%nums%
call set str3=%%var:~%1,%%i%%%num%
call echo %%str1:~0,15%% %%str2:~0,20%% %%str3:~0,15%%
if %%i==-3 echo\
)
goto :eof
:san
set str1=%%var:"=%%%num%
set str2=删除var中的所有^"号%num%
set str3=%var:"=%%nums%
call echo %%str1:~0,13%% %%str2:~0,23%% %%str3:~0,30%%
set str1=%%var:\=%%%num%
set str2=删除var中的所有\号%num%
set str3=%var:\=%%nums%
call echo %%str1:~0,13%% %%str2:~0,23%% %%str3:~0,30%%
set str1=%%var::=%%%num%
set str2=删除var中的所有:号%num%
set str3=%var::=%%nums%
call echo %%str1:~0,13%% %%str2:~0,23%% %%str3:~0,30%%
echo\
set str1=%%var:"=好%%%num%
set str2=替换var中的所有^"号为好字%num%
set str3=%var:"=好%%nums%
call echo %%str1:~0,12%% %%str2:~0,20%% %%str3:~0,30%%
set str1=%%var:\=好%%%num%
set str2=替换var中的所有\号为好字%num%
set str3=%var:\=好%%nums%
call echo %%str1:~0,12%% %%str2:~0,20%% %%str3:~0,30%%
set str1=%%var::=好%%%num%
set str2=替换var中的所有:号为好字%num%
set str3=%var::=好%%nums%
call echo %%str1:~0,12%% %%str2:~0,20%% %%str3:~0,30%%
echo\
set str1=%%var:*"=%%%num%
set str3=%var:*"=%%nums%
echo 删除var中的第一次出现的^"号及其前面的所有字符
call echo %%str1:~0,15%% %%str3:~0,30%%
echo.
set str1=%%var:*\=%%%num%
set str3=%var:*\=%%nums%
echo 删除var中的第一次出现的\号及其前面的所有字符
call echo %%str1:~0,15%% %%str3:~0,30%%
echo.
set str1=%%var:*:=%%%num%
set str3=%var:*:=%%nums%
echo 删除var中的第一次出现的:号及其前面的所有字符
call echo %%str1:~0,15%% %%str3:~0,30%%
echo\
set str1=%%var:*"=ppp%%%num%
set str3=%var:*"=ppp%%nums%
echo 替换var中的第一次出现的^"号及其前面的所有字符为ppp
call echo %%str1:~0,15%% %%str3:~0,30%%
echo.
set str1=%%var:*\=ppp%%%num%
set str3=%var:*\=ppp%%nums%
echo 替换var中的第一次出现的\号及其前面的所有字符为ppp
call echo %%str1:~0,15%% %%str3:~0,30%%
echo.
set str1=%%var:*:=ppp%%%num%
set str3=%var:*:=ppp%%nums%
echo 替换var中的第一次出现的:号及其前面的所有字符为ppp
call echo %%str1:~0,15%% %%str3:~0,30%%
echo\
goto :eof

五、批处理Set命令详解补充篇

1、替换变量值的内容

语法：set newVar="oldVar:str1=str2%
将变量oldVar的值中的str1替换成str2,并将替换后的变量值赋给newVar.
看例子

@echo off
set a=bbs.verybat.cn
echo 替换前的值: "%a%"
set var=%a:bbs=sss%
echo 替换后的值: "%var%"
pause

对比一下,我们发现他把变量%a%的bbs给替换掉了,换成了sss.

批处理bat设置固定IP地址和自动IP地址

在我个人的使用经验中,我有不同的工作环境,比如公司和家里,公司要求固定IP,而家里则使用自动获取IP的方式,所以我就在网上找了这段代码,并且经过自己的修改,可以直接双击运行就可以,方便IP地址的切换. 这里主要使用netsh命令,不太明白的可以自己去百度查,这里就不列举它的用法了,具体代码如下: 固定IP和DNS.bat 复制代码代码如下: @echo off cls color 0A Echo *************************************************
IP地址自动设置的批处理代码分享

批处理文件是将一系列命令按一定的顺序集合为一个可执行的文本文件,其扩展名为BAT或者CMD.这些命令统称批处理命令. 小知识:可以在键盘上按下Ctrl+C组合键来强行终止一个批处理的执行过程. 一般常规的批处理命令,按照自上而下的顺序逐行执行,也就是说,只有第一行命令执行之后,才可能执行第二行,第二行执行之后,才可以执行到第三行.....如此依次执行.那么,如果对于不同的情况,需要执行不同的既定操作,常规的执行规则显然是无法完成任务的,这种应用场景下怎么办呢?我们就需要引入流程跳转的概念,即就是
批处理获取网卡名称的代码（附修改IP、网关、DNS脚本）

复制代码代码如下: ::用ipconfig /all命令获取网卡名称. FOR /F "tokens=2*" %%i IN ('ipconfig/all^|find /i "Ethernet adapter "') DO set name=%%j ::用for命令删除网卡名称后面的冒号. FOR /F "tokens=1* delims=:" %%i in ("%name%") do set 网卡名称=%%i 套用上面的脚本
BAT批处理中的字符串处理详解(字符串截取)

下面对这些功能一一进行讲解. 1.截取字符串截取字符串可以说是字符串处理功能中最常用的一个子功能了,能够实现截取字符串中的特定位置的一个或多个字符.举例说明其基本功能: 复制代码代码如下: @echo off set ifo=abcdefghijklmnopqrstuvwxyz0123456789 echo 原字符串(第二行为各字符的序号): echo %ifo% echo 123456789012345678901234567890123456 echo 截取前5个字符: echo %if
批处理经典入门教程！(从不懂到高手)第1/5页

我们补充说明:批处理相对来说是比较简单的语言,大家可以通过多写多看别人的实例来学习,不懂的百度一下. 这是一篇技术教程,真心诚意会用很简单的文字表达清楚自己的意思,只要你识字就能看懂,就能学到知识.写这篇教程的目的,是让每一个看过这些文字的朋友记住一句话:如果爱可以让事情变的更简单,那么就让它简单吧!看这篇教程的方法,就是慢!慢慢的,如同品一个女人.一杯茗茶,你会发现很多以前就在眼前的东西突然变的很遥远,而有些很遥远的东西却又突然回到了眼前.. 先概述一下批处理是个什么东东.批处理的定义,至今我
windows批处理命令教程

批处理文件是无格式的文本文件,它包含一条或多条命令.它的文件扩展名为 .bat 或 .cmd.在命令提示下键入批处理文件的名称,或者双击该批处理文件,系统就会调用Cmd.exe按照该文件中各个命令出现的顺序来逐个运行它们.使用批处理文件(也被称为批处理程序或脚本),可以简化日常或重复性任务.当然我们的这个版本的主要内容是介绍批处理在入侵中一些实际运用,例如我们后面要提到的用批处理文件来给系统打补丁.批量植入后门程序等.下面就开始我们批处理学习之旅吧. 一.简单批处理内部命令简介 1.echo
批处理、VBS实现自动设置IP、默认网关、DNS、WINS、IE代理(全)

因为公司有同事负责大连.沈阳两个城市,经常在两地来回走动,到每个城市后,都要自己手动更改相应的网络配置,况且到外地时住的是酒店, 酒店上网是自动获得IP,又要将网络设置取消,真的很麻烦!于是想起写一个批处理!来解决这个问题!主要用到的命令是netsh. -.第一种方法是将两地的网络配置先进行本机设置,然后再导出,等用到的时候,再分别导入. 1.将现有的配置导出到d:\dalian.txt中: netsh –c interface dump > d:\dalian.txt 2.将之前导出的d:\d
获取外网IP地址的批处理代码

复制代码代码如下: ::========================================== :: IP.bat :: v0.1 :: jinminghou.cn@2009-12-22 ::========================================== @echo off title GetIP set ip=unknown echo On Error Resume Next:Set oDOM=WScript.GetObject("http://www.j
bat批处理 if 命令示例详解

if 命令示例详解 if,正如它E文中的意思,就是"如果"的意思,用来进行条件判断.翻译过来的意思就是:如果符合某一条件,便执行后面的命令. 主要用来判断,1.两个"字符串"是否相等:2.两个数值是大于.小于.等于,然后执行相应的命令. 当然还有特殊用法,如结合errorlevel:if errorlevel 1 echo error 或者结合defined(定义的意思):if defined test (echo It is defined) else echo
Windows下用命令行修改IP地址的方法详解(附批处理文件)

由于我所处的地方要经常在不同的网络之间切换,比如局域网.系统内部网和外网(光是外网我要常常在3个ADSL网之间切换).我之前一直用的方法是在本机上设置多个不同网段的IP,然后切换路由(Route),这样不同的网段通过不同的网关出去,就可以达到同时访问多个网络的目的.但是这样我发现经常可能出现一些问题,所以我决定用最原始的方法来解决,那就是在要使用某一个网段的时候就只用这个网段的IP,这样就需要不停的更换IP地址.当然,在Windows的"网络连接"属性中这样的更改是很麻烦的,不过还好的
批处理命令Start的使用介绍

Start 启动单独的"命令提示符"窗口来运行指定程序或命令.如果在没有参数的情况下使用,start 将打开第二个命令提示符窗口. 语法 start ["title"] [/dPath] [/i] [/min] [/max] [{/separate | /shared}] [{/low | /normal | /high | /realtime | /abovenormal | belownormal}] [/wait] [/b] [FileName] [param

批处理 Set 命令详解 让你理解set命令

目录