用vbs检索在运行对话框中键入的一系列命令的代码

问：
您好，脚本专家！有时，我在运行对话框中键入了多个命令，随后想要对其进行检索。我知道我最近使用过的命令缓存在某个地方，因为当我开始在运行对话框中键入时，它们便会显示出来。如何使用脚本检索这些命令？
-- KJ
答：
您好，KJ。您知道，一看到您的问题，我们首先想到的是：为什么我们没有想过这个问题？不用说，脚本专家使用运行对话框已经有好多年了，并且我们也非常清楚地知道，最近使用的命令（如果您统计过的话，是最近使用过的 26 个）缓存在计算机上的某个地方。然而，我们从未编写过可检索此列表的脚本。我们怎么能忽略如此明显的事情呢？
注意：事实上，令人吃惊的绝不仅限于我们已忽略了如此明显的事情。例如，到目前为止，脚本专家已在其当前所在的大厦中呆了大约一年的时间了，然而就在几个星期前，编写本专栏的脚本专家才发现有从其办公室通往楼下大厅的楼梯。
稍加摸索后，我们发现该信息存储在注册表中；更确切地说，它作为单个注册表值存储在注册表项 HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\RunMRU 中。这样不是很好吗？当然很好；毕竟，这使得我们能够编写以下脚本：


代码如下:

Const HKEY_CURRENT_USER = &H80000001 
strComputer = "." 
Set objRegistry = GetObject("winmgmts:\\" & strComputer & "\root\default:StdRegProv") 
strKeyPath = "Software\Microsoft\Windows\CurrentVersion\Explorer\RunMRU" 
objRegistry.EnumValues HKEY_CURRENT_USER, strKeyPath, arrValueNames, arrValueTypes 
For Each strValue in arrValueNames 
    If Len(strValue) = 1 Then 
        objRegistry.GetStringValue HKEY_CURRENT_USER,strKeyPath,strValue,strRunCommand 
        intLength = Len(strRunCommand) 
        strRunCommand = Left(strRunCommand, intLength - 2) 
        Wscript.Echo strRunCommand 
    End If    
Next

该脚本连接到 RunMRU 项，然后枚举在此处找到的所有值的值。（是的，我们知道：值的值？这便是注册表术语的有趣之处。）要实现该功能，该脚本首先定义一个名为 HKEY_CURRENT_USER 的常量，并将该值设置为 &H80000001；稍后将使用该常量来告知脚本要处理的注册表配置单元。然后，我们连接到本地计算机上的 WMI 服务，务必绑定到 root\default 命名空间，即 WMI 注册表提供程序的主目录。
注意：我们可使用此相同的脚本来检索远程计算机中最近使用过的命令吗？当然可以；只需将远程计算机的名称分配给变量 strComputer 即可。
连接到 WMI 服务后，将值 Software\Microsoft\Windows\CurrentVersion\Explorer\RunMRU 分配给名为 strKeyPath 的变量。然后使用 EnumValues 方法来获取 RunMRU 项中所有注册表值的集合：
objRegistry.EnumValues HKEY_CURRENT_USER, strKeyPath, arrValueNames, arrValueTypes
正如您所看到的那样，我们将四个参数传递给 EnumValues：
参数
 说明
HKEY_CURRENT_USER
 可在其中找到信息的注册表配置单元。
strKeyPath
 HKCU 配置单元中 RunMRU 项的路径。
arrValueNames
 这是一个“输出”参数，用作存储所有注册表值名称的位置。我们所要做的就是为 EnumValues 提供一个变量名；然后，EnumValues 将使用 RunMRU 中的所有值名称来填充此变量。
arrValueTypes
 另一输出参数，此参数含有与 RunMRU 中找到的每个值相对应的数据类型。这个参数是必需的，但是由于在 RunMRU 中找到的值的数据类型均为 REG_SZ，因此，我们实际上在脚本中并不使用它。
事实证明，在“运行”对话框中键入的每个命令在注册表中都有其对应值；通过使用字母 A 到 Z 为这些值分配了名称（这也就解释了为何在注册表中只有 26 个最近使用的命令被跟踪的原因）。在注册表中，RunMRU 如下图所示：

执行 EnumValues 方法后，我们将返回所有这些值名称的集合；换言之，我们的集合将由字母 A 到 Z 组成。非常不错，只是该集合中不包含任何实际命令。要获得这些命令（这是我们的最终目的），我们需要连接到并读取注册表中 26 个值中的每个值。
我们能这样做吗，我们能很容易地连接到注册表中 26 个值并读取每一个值吗？当然可以；事实上，这就是以下这段代码所执行的操作：


代码如下:

For Each strValue in arrValueNames 
    If Len(strValue) = 1 Then 
        objRegistry.GetStringValue HKEY_CURRENT_USER,strKeyPath,strValue,strRunCommand 
        intLength = Len(strRunCommand) 
        strRunCommand = Left(strRunCommand, intLength - 2) 
        Wscript.Echo strRunCommand 
    End If    
Next

您说对了：乍一看，它是有点可怕，不是吗？告诉您原因吧，让我们向您介绍一个该 For Each 循环的简化版本，然后我再解释为何将一些附加代码添加到此循环中。该简化循环如下：
For Each strValue in arrValueNames
    objRegistry.GetStringValue HKEY_CURRENT_USER,strKeyPath,strValue,strRunCommand
    Wscript.Echo strRunCommand
Next
在此我们所要做的就是建立一个循环，该循环将遍历所有注册表值。要读取其中的每个值，我们只需调用 GetStringValue 方法：
objRegistry.GetStringValue HKEY_CURRENT_USER,strKeyPath,strValue,strRunCommand
GetStringValue 所传递的四个参数：常量 HKEY_CURRENT_USER；变量 strKeyPath；变量 strValue（代表各个值的名称，例如 A、B 或 C）；名为 strRunCommand 的输出参数。通过使用此输出参数，我们只需指定一个变量名称，GetStringValue 方法会将注册表值的值（即，相应的“运行”命令）分配给它。调用 GetStringValue 后，我们将回显 strRunCommand，继续循环，并处理集合中的下一个值。
对于该简化的 For Each 循环已讲了不少了；而真正的 For Each 循环中的所有额外代码又怎样呢？之所以使用额外代码主要是为了可为我们提供稍好些的输出。例如，在 RunMRU 项中，有一个名为 MRUList 的注册表值。这并不代表一个实际的命令；而是代表最近使用的命令的先后出现顺序。这对我们而言并不重要（至少今天不重要），因此我们宁愿跳过该 MRUList 值。这就是下面的代码所要执行的操作：
If Len(strValue) = 1 Then
在此行代码中，我们使用 Len 函数来检查值名称中的字符数。如果字符数（长度）等于 1，我们将继续进行并读取该值。如果长度不等于 1（显而易见，当 MRUList 具有 7 个字符时，就属于这种情况），则我们只需跳过该值并移至集合中的下一项即可。
我们添加的另一小段代码是：
intLength = Len(strRunCommand)
strRunCommand = Left(strRunCommand, intLength - 2)
如果您查看注册表，您会发现所有命令的末尾都添加了一个 \1。如果需要的话，可将其保留下来，不过很容易将其去掉。我们所要做的是确定命令的长度，然后使用 Left 函数返回字符串中的第一个 x 字符。x 等于什么？它等于字符总数减 2。这就意味着，我们要获取除最后 2 个字符（即 \1）以外的所有字符，并将它们回显到屏幕上。
至此您已实现了您的目的：一个可返回在运行对话框所键入的最近使用的命令的脚本。我们仍不知道神秘的楼梯到底通向哪里，但我们需要先做重要的事情。